public string warnSpellType;
public string SpeakString;
public string warnPerson;
public string warnTimerName;
public string note;


function main()
{
    SpeakSync("general warnings");

}

trigger("[@trash@] @warnPerson@ assumes a defensive fighting style.")
{
    string s;
    string timername;
    string timer2name;
    unsigned long Timer1MS;
    unsigned long Timer2MS;


    Timer1MS=((3*60)-20)*1000;
    Timer2MS=(3*60)*1000;

    timername = "";
    timer2name = "";

    strcat(timername,warnPerson);
    strcat(timername," defensive is down in 30 seconds");
    strcat(timer2name,warnPerson);
    strcat(timer2name," defensive is down now");
    SpeakSync(warnPerson, " is defensive");
    RemoveTimer(timername);
    RemoveTimer(timer2name);
    AddTimer(timername,Timer1MS,SND_TTS,timername);
    AddTimer(timer2name,Timer2MS,SND_TTS,timer2name);
}


// *********************
// Mod Rod Functions
// *********************
//[Fri Jan 10 23:15:32 2003] You experience a mystical transvergance.  You have taken 156 points of damage.
trigger("[@trash@] You experience a mystical transvergance.@trash@")
{
    RemoveTimer("ModRod:Timer");
    AddTimer("ModRod:Timer", 300000, SND_SYNCTTS, "Mod Rod Available");
}

trigger("[@trash@] You modulate@trash@")
{
    RemoveTimer("ModRod:Timer");
    AddTimer("ModRod:Timer", 300000, SND_SYNCTTS, "Mod Rod Available");
}

//[Tue Feb 20 02:36:20 2001] Rezzin modulates.
trigger("[@trash@] @warnPerson@ modulates@trash@")
{
    SpeakSync(warnPerson, " used mod rod");
}

//[Wed Jan 01 22:32:21 2003] Xiff experiences a mystical transvergance.
trigger("[@trash@] @warnPerson@ experiences a mystical transvergance@trash@")
{
    SpeakSync(warnPerson, " used mod rod");
}
// ***********************
// End Mod Rod Functions
// ***********************


// ***********************
// Watch Functions
// ***********************
alias("watch @warnPerson@")
{
    string s;
    string s1;
    string s2;

    SpeakSync("Watching ", warnPerson);


    //[Wed May 15 21:00:03 2002] a festering hag hits YOU for 3 points of damage.
    s="";
    s1="";
    s2="";
    strcat(s,"[@trash@] @trash@ ", warnPerson, " for @trash@ point@trash@ damage.");
    strcat(s1,"warn:watchAlert:damage ", warnPerson);
    strcat(s2,"Damage:",warnPerson);
    AddTrigger(s2,s,SND_ALIAS,s1);

    // [Fri Sep 27 21:31:18 2002] Mennoly tries to pierce a Darkpaw defiler, but a Darkpaw defiler's magical skin absorbs the blow!
    s="";
    s1="";
    s2="";
    strcat(s,"[@trash@] @trash@ tries to @trash@", warnPerson, ", but @trash@'s magical skin absorbs the blow!");
    strcat(s1,"warn:watchAlert:absorb ", warnPerson);
    strcat(s2,"Absorb:",warnPerson);
    AddTrigger(s2,s,SND_ALIAS,s1);

}

alias("warn:watchAlert:damage @warnPerson@")
{
    if (AddTimer(warnPerson, 5000, SND_ALIAS, "warnRemoveTimer %warnPerson%"))
    {
        SpeakSync(warnPerson, " is being hit");
    }
}

alias("warn:watchAlert:absorb @warnPerson@")
{
    if (AddTimer(warnPerson, 5000, SND_ALIAS, "warnRemoveTimer %warnPerson%"))
    {
        SpeakSync(warnPerson, " absorbing damage");
    }
}

alias("ignore @warnPerson@")
{
    string s;

    s = "Damage:";
    strcat(s, warnPerson);
    RemoveTrigger(s);

    s = "Absorb:";
    strcat(s, warnPerson);
    RemoveTrigger(s);

    RemoveTimer(warnPerson);
    SpeakSync("Ignoring hits to ", warnPerson);
}

alias("warnRemoveTimer @warnTimerName@")
{
    RemoveTimer(warnTimerName);
}
// ****************************
// End Watch Functions
// ****************************


alias("note @note@")
{
    unsigned long pos;
    boolean fileexist;

    fileexist = FileExists("eqnotes.txt");


    if (fileexist == false)
    {
        Create(0, "eqnotes.txt");
    }
    else
    {
        Open(0, "eqnotes.txt");
    }
    pos = Size(0);
    Seek(0,pos);
    WriteLN(0, note);
    Close(0);
    Speak("Note entered");

}